Anemometer Test Rig

/*  Anemometer Test Rig Code
    By Matt Little  21/9/2023

    This controls a motor to a set speed in order to rotate an anemometer
    An anemometer gives out pulses/signal that relates to wind speed
    This unit is to check the output aligns with the speed and to test linearity
    of anemometer.
    Designed to test my wind sensor unit at low output speeds.

    Design uses an L298N Dual Bridge Motor controller:
    https://lastminuteengineers.com/l298n-dc-stepper-driver-arduino-tutorial/

    It also uses a 25GA370 DC 12V 250rpm geared motor with encoder
    https://www.ebay.co.uk/itm/185260189825
    Encoder wiring info:
    Red: Motor power + (exchange can control rotating and reversing of motor)
    Black: Coding power- negative (polarity cannot be wrong 3.3-5V)
    Green: Signal feedback (motor rotate 1 circle 11 signal)
    Yellow: Signal feedback (motor rotate 1 circle 11 signal)
    Blue: Coding power + Positive (polarity cannot be wrong 3.3-5V)
    White: Motor power - (exchange can control rotating and reversing of motor)
    So motor rotating 1 times = 11 pulses on encoder.
    No-load rotating speed at 12V = 250rpm.

    So output shaft rotating 1 time = 34 motor times = 374 encoder pulses??

*/

// ******** This is for Scheduling Tasks **************************
// Must include this library from Arduino IDE Library Manager
// https://github.com/arkhipenko/TaskScheduler
#include <TaskScheduler.h>
#define _TASK_SLEEP_ON_IDLE_RUN    // Enable 1 ms SLEEP_IDLE powerdowns between tasks if no callback methods were invoked during the pass
// Callback methods prototypes
void t1SCallback();
Task t1S    (TASK_SECOND, TASK_FOREVER, &t1SCallback);
Scheduler runner;

#define enA   6
#define in1   5
#define in2   4

#define FREQ_DELAY      5       // debounce delay time in Seconds 
#define FREQ_PIN_0      2
#define FREQ_PIN_1      3
#define MIN_PWM         55

unsigned int pulse_counter_0 = 0;
unsigned int pulse_counter_1 = 0;
long int     freq_adjust_time = millis();
long int     start_time;

#define RPM_CONV    374      // Conversion factor from pulse count to shaft rpm    
double      shaftRPM = 0.0;
double      pwmOutput = 0;
double      rpmSetpoint = 0;

#include <PID_v1.h>
//Specify the links and initial tuning parameters
double Kp = 0.3, Ki = 0.2, Kd = 0.1;
PID myPID(&shaftRPM, &pwmOutput, &rpmSetpoint, Kp, Ki, Kd, DIRECT);

// *********** These are global variables ***************************
String        inputString = "";           // a String to hold incoming data
bool          stringComplete = false;     // Checks if the string is complete

void t1SCallback() {
  if (!t1S.isFirstIteration())
  {
    // Calculate shaft RPM from Pulses:
     shaftRPM = ((double)pulse_counter_0 / (double)RPM_CONV) / (double)((millis() - start_time) / 60000.0);

    start_time = millis();  // Reset the start time.
    Serial.print(F("PWM: "));
    Serial.print(pwmOutput);
    Serial.print(F("\tP0: "));
    Serial.print(pulse_counter_0);
    Serial.print(F("\tP1: "));
    Serial.print(pulse_counter_1);
    Serial.print(F("\tRPM: "));
    Serial.println(shaftRPM);
    pulse_counter_0 = 0;
    pulse_counter_1 = 0;

  }
}

//ISR Functions for pulse counting
void ISR_PULSE_0()
{
  pulse_counter_0++;    // Increment the counter
}

//ISR Functions for pulse counting
void ISR_PULSE_1()
{
  pulse_counter_1++;    // Increment the counter
}

void setup() {
  // initialize serial communication:
  Serial.begin(9600);
  // reserve 50 bytes for the Strings:
  inputString.reserve(50);

  Serial.println(F("Anemometer Test Start"));
  // Set up motor:
  pinMode(enA, OUTPUT);
  pinMode(in1, OUTPUT);
  pinMode(in2, OUTPUT);
  // Set initial rotation direction
  digitalWrite(in1, HIGH);
  digitalWrite(in2, LOW);

  // Sort out ISR for pulse counting
  attachInterrupt(digitalPinToInterrupt(FREQ_PIN_0), ISR_PULSE_0, FALLING);
  attachInterrupt(digitalPinToInterrupt(FREQ_PIN_1), ISR_PULSE_1, FALLING);

  // Set up Scheduler:
  runner.init();
  runner.addTask(t1S);
  t1S.enable();

  // Set PWM
  analogWrite(enA, pwmOutput); // Send PWM signal to L298N Enable pin
  start_time = millis();

  //turn the PID on
  myPID.SetMode(AUTOMATIC);

}

void loop()
{
  // Deal with schedules tasks
  runner.execute();

  myPID.Compute();
  analogWrite(enA, pwmOutput); // Send PWM signal to L298N Enable pin

  //  if ( millis() > freq_adjust_time + (FREQ_DELAY * 1000))
  //  {
  //    pwmOutput = pwmOutput + 5;
  //    if (pwmOutput > 255)
  //    {
  //      pwmOutput = MIN_PWM;
  //    }
  //    analogWrite(enA, pwmOutput); // Send PWM signal to L298N Enable pin
  //    freq_adjust_time = millis();
  //  }

  // Check for serial data
  if (stringComplete == true)
  {
    // Convert the inputString to the rpmSetpoint
    if (inputString.toDouble() < 20)
    {
      Serial.print(inputString.toDouble());
      Serial.println("\t TOO LOW!");
    }
    else if (inputString.toDouble() > 250)
    {
      Serial.print(inputString.toDouble());
      Serial.println("\t TOO HIGH!");
    }
    else
    {
      rpmSetpoint = inputString.toDouble();
      Serial.print("RPM Setpoint:\t");
      Serial.println(rpmSetpoint);
    }
    inputString = "";
    stringComplete = false;
  }
}

/*
  SerialEvent occurs whenever a new data comes in the hardware serial RX. This
  routine is run between each time loop() runs, so using delay inside loop can
  delay response. Multiple bytes of data may be available.
*/
void serialEvent()
{
  while (Serial.available()) {
    // get the new byte:
    char inChar = (char)Serial.read();
    // add it to the inputString:
    inputString += inChar;
    // if the incoming character is a newline, set a flag so the main loop can
    // do something about it:
    if (inChar == '\n') {
      stringComplete = true;
    }
  }
}